Display Content Query Web Part Results in a Grid / Table

Overview and Objective

Out of the box, MOSS’ Content Query Web Part (CQWP) displays its results in a list format, similar to search results. It is also possible to display the results in a grid format (i.e. HTML table format). Grid formats are better in some circumstances. I describe how to achieve that effect in this article.

Business Scenario

I have worked with a client on an enterprise-wide MOSS rollout. We have designed their taxonomy such that projects are first class citizens in the hierarchy and have their own top level site. Project managers maintain a singleton list of project summary information, such as title, budget, expected completion date, remaining budget and other summary type fields. By "singleton" I mean a custom SharePoint list guaranteed to contain only one item. Simplistically, it looks like this:

The technical approach is much the same as described here (http://paulgalvin.spaces.live.com/blog/cns!1CC1EDB3DAA9B8AA!447.entry). The CQWP uses an XSL transform to emit HTML for the browser to render.

I always envision the result before diving into the XSL because XSL is a nightmare. Here’s my desired result:

HTML like this generates that result:

<html>
 <body>
 <center>
 <table border=1>

<!-- Labels -->
 <tr bgcolor=blue>
 <td><font color=white><b>Project Name</b></font></td>
 <td align=right><font color=white><b>Complete Date</b></font></td>
 <td align=right><font color=white><b>Budget</b></font></td>
 <td align=right><font color=white><b>Actual Expense</b></font></td>
 <td><font color=white><b>Overall Status</b></font></td>
 </tr>

<tr>
 <td>Re-wire computer room.</td>
 <td align=right>02/01/08</td>
 <td align=right>22,500.00</td>
 <td align=right>19,000.00</td>
 <td>In Progress</td>
 </tr>

<tr>
 <td>Provision servers for SQL Upgrade</td>
 <td align=right>04/01/08</td>
 <td align=right>7,500.00</td>
 <td align=right>0.00</td>
 <td>Planned</td>
 </tr>

</table>
 </center>
 </body>
</html>

Approach

Follow these steps to create the grid:

Identify the components of the grid (rows/columns).
Define and create necessary site columns.
Create sub sites for the projects and singleton lists.
Add the CQWP to a web page and configure it to search for your lists.
Modify the CQWP’s XML to gather up the additional columns.
Modify the XSL to generate a table.

I’m going to concentrate on number six. Numbers one through four are straight-forward and something that any CQWP user has already done. Number five has been well-documented by others including this exhaustive screen-shot laden article from MSDN here (http://msdn2.microsoft.com/en-us/library/bb897399.aspx) and Heather Solomon’s blog here (http://www.heathersolomon.com/blog/articles/CustomItemStyle.aspx).

Nuts And Bolts

Begin and implement steps one through five as per the MSDN documentation and Heather Solomon’s article.

At this point, you’ve added your CQWP to the page and you have your <CommonViewFields> configured as necessary.

Following the usual steps, I get these intermediate results:

1. Create a content type, a templatized custom list for that content type and two sites. Here is the content type:

Here is the site structure:

2. Add the CQWP after creating my project subsites and singleton project summary lists:

3. Add all the additional information I want via the <CommonViewFields>:

        <property name="CommonViewFields" type="string">Project_x0020_Name;Project_x0020_Expenses;Project_x0020_Status;Project_x0020_Start_x0020_Date;Project_x0020_End_x0020_Date;Project_x0020_Budget</property>

Note that I had to keep all the property fields on one line or it would not work (CQWP would tell me that the query returned no items).

4. At this point, we’re ready to move beyond the MSDN article and flip on over to Heather Solomon’s article. Follow her steps starting near step #5 to create a customized / unghosted version of ItemStyle.xsl. I follow Heather’s advice, up through step 11 and get these intermediate results:

4.1: Name my XSL template as follows:

<xsl:template name="Grid" match="Row[@Style=’Grid’]" mode="itemstyle">

I also slightly modify her suggested <xsl:for-each …> by adding a <br/> tag to provide a cleaner listing:

    <xsl:for-each select="@*">
      P:<xsl:value-of select="name()" /><br/>
    </xsl:for-each>

4.2: I modify the web part, go to appearance and select my "Grid" style:

Apply the change and here is the result:

We can see from the above that the fields we want (Project name, expense, status, etc) are available for us to use when we emit the HTML. Not only that, but we see the names by which we must reference those columns in the XSL. For example, we reference Project Status as "Project_x005F_x0020_Name".

At this point, we depart from Heather’s blog and from the shoulders of these giants, I add my own little bit.

ContentQueryMain.xsl

NOTE: When making changes to both ContentQueryMain.xsl as well as ItemStyle.xsl, you need to check those files back in before you see the effect of your changes.

For grid-making purposes, MOSS uses two different XSL files to produce the results we see from a CQWP. To generate the previous bit of output, we modified ItemStyle.xsl. MOSS actually uses another XSL file, ContentQueryMain.xsl to in conjunction with ItemStyle.xsl to generate its HTML. As its name implies, ContentQueryMain.xsl is the "main" XSL that controls the overall flow of translation. It iterates through all the found items and passes them one by one to templates in ItemStyle.xsl. We’ll modify ItemStyle.xsl to generate the open <table> tag before emitting the first row of data and the closing <table> tag after emitting the last row. To accomplish this, ContentQueryMain.xsl is modified to pass two parameters to our "grid" template in ItemStyle.xsl, "last row" and "current row". ItemStyle.xsl uses these to conditionally emit the necessary tags.

Using Heather Solomon’s technique, we locate ContentQueryMain.xsl. It is located in the same place as ItemStyle.xsl. This screen shot should help:

We need to make the following changes:

Modify an xsl template, "CallItemTemplate" that actually invokes our Grid template in ItemStyle.xsl. We will pass two parameters to the Grid template so that it will have the data it needs to conditionally generate opening and closing <table> tags.
Modify another bit of ContentQueryMain.xsl that calls the "CallItemTemplate" to pass it a "LastRow" parameter so that LastRow may be passed on to our Grid template.

Locate the template named "OuterTemplate.CallItemTemplate" identified by the string:

  <xsl:template name="OuterTemplate.CallItemTemplate">

Replace the whole template as follows:

  <xsl:template name="OuterTemplate.CallItemTemplate">
    <xsl:param name="CurPosition" />

    <!--
      Add the "LastRow" parameter.
      We only use it when the item style pass in is "Grid".
    -->
    <xsl:param name="LastRow" />

    <xsl:choose>
      <xsl:when test="@Style='NewsRollUpItem'">
        <xsl:apply-templates select="." mode="itemstyle">
          <xsl:with-param name="EditMode" select="$cbq_iseditmode" />
        </xsl:apply-templates>
      </xsl:when>
      <xsl:when test="@Style='NewsBigItem'">
        <xsl:apply-templates select="." mode="itemstyle">
          <xsl:with-param name="CurPos" select="$CurPosition" />
        </xsl:apply-templates>
      </xsl:when>
      <xsl:when test="@Style='NewsCategoryItem'">
        <xsl:apply-templates select="." mode="itemstyle">
          <xsl:with-param name="CurPos" select="$CurPosition" />
        </xsl:apply-templates>
      </xsl:when>

      <!--
              Pass current position and lastrow to the Grid itemstyle.xsl template.
              ItemStyle.xsl will use that to emit the open and closing <table> tags.
      -->
      <xsl:when test="@Style='Grid'">
        <xsl:apply-templates select="." mode="itemstyle">
          <xsl:with-param name="CurPos" select="$CurPosition" />
          <xsl:with-param name="Last" select="$LastRow" />
        </xsl:apply-templates>
      </xsl:when>

      <xsl:otherwise>
        <xsl:apply-templates select="." mode="itemstyle">
        </xsl:apply-templates>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

The comments describe the purpose of the changes.

Of course, the "OuterTemplate.CallItemTemplate" is itself called from another template. Locate that template by searching for this text string:

<xsl:template name="OuterTemplate.Body">

Scroll through the instructions in OuterTemplate.Body and insert the LastRow parameter as follows (shown as a comment in italics):

<xsl:call-template name="OuterTemplate.CallItemTemplate">
  <xsl:with-param name="CurPosition" select="$CurPosition" />
  <!-- Insert the LastRow parameter. -->
  <xsl:with-param name="LastRow" select="$LastRow"/>
</xsl:call-template>

After all of this, we finally have things set up properly so that our ItemStyle.xsl can emit <table> tags at the right place.

ItemStyle.Xsl

NOTE: Again, check in ItemStyle.xsl after making any changes so that you see the effect of those changes.

We have two tasks here:

Replace the entire Grid template. You can copy/paste from below.
Add some mumbo jumbo outside the template definition that enables "formatcurrency" template to work. (You can tell that I have a tenuous handle on XSL).

First, near the top of ItemStyle.xsl, add this line:

  <!-- Some mumbo jumbo that enables us to display U.S. currency. -->
  <xsl:decimal-format name="staff" digit="D" />

  <xsl:template name="Default" match="*" mode="itemstyle">

Note that I added it directly before the <xsl:template name="Default" …> definition.

Next, go back to our Grid template. Replace the entire Grid template with the code below. It is thoroughly commented, but don’t hesitate to email me or leave comments on my blog if you have questions.

  <xsl:template name="Grid" match="Row[@Style='Grid']" mode="itemstyle">

    <!--
      ContentMain.xsl passes CurPos and Last.
      We use these to conditionally emit the open and closing <table> tags.
    -->
    <xsl:param name="CurPos" />
    <xsl:param name="Last" />

    <!-- The following variables are unmodified from the standard ItemStyle.xsl -->
    <xsl:variable name="SafeImageUrl">
      <xsl:call-template name="OuterTemplate.GetSafeStaticUrl">
        <xsl:with-param name="UrlColumnName" select="'ImageUrl'"/>
      </xsl:call-template>
    </xsl:variable>
    <xsl:variable name="SafeLinkUrl">
      <xsl:call-template name="OuterTemplate.GetSafeLink">
        <xsl:with-param name="UrlColumnName" select="'LinkUrl'"/>
      </xsl:call-template>
    </xsl:variable>
    <xsl:variable name="DisplayTitle">
      <xsl:call-template name="OuterTemplate.GetTitle">
        <xsl:with-param name="Title" select="@Title"/>
        <xsl:with-param name="UrlColumnName" select="'LinkUrl'"/>
      </xsl:call-template>
    </xsl:variable>
    <xsl:variable name="LinkTarget">
      <xsl:if test="@OpenInNewWindow = 'True'" >_blank</xsl:if>
    </xsl:variable>

    <!--
      Here we define a variable, "tableStart".  This contains the HTML
      that we use to define the opening of the table as well as the column
      labels.  Note that if CurPos = 1, it includes the HTML in a CDATA tag.
      Otherwise, it will be empty.

      The value of tableStart is emited every time ItemStyle is called via
      ContentQueryMain.xsl.
    -->
    <xsl:variable name="tableStart">
      <xsl:if test="$CurPos = 1">
        <![CDATA[
        <table border=1>
          <tr bgcolor="blue">
            <td><font color="white"><b>Project Name</b></font></td>
            <td align="right"><font color="white"><b>Complete Date</b></font></td>
            <td align="right"><font color="white"><b>Budget</b></font></td>
            <td align="right"><font color="white"><b>Actual Expense</b></font></td>
            <td><font color="white"><b>Overall Status</b></font></td>
          </tr>
        ]]>
      </xsl:if>
    </xsl:variable>

    <!--
      Another variable, tableEnd simply defines the closing table tag.

      As with tableStart, it's always emited.  This is why its value is
      assigned conditionally based upon whether we've been passed the last
      row by ContentQueryMain.xsl.
    -->
    <xsl:variable name="tableEnd">
      <xsl:if test="$CurPos = $Last">
        <![CDATA[ </table> ]]>
      </xsl:if>
    </xsl:variable>

    <!--
      Always emit the contents of tableStart.  If this is not the first
      row passed to us by ContentQueryMain.xsl, then we know its value
      will be blank.

      Disable output escaping because when tableStart it not blank, it
      includes actual HTML that we want to be rendered by the browser.  If
      we don't tell the XSL parser to disable output escaping, it will generate
      stuff like "&lt;table&gt;" instead of "<table>".
    -->
    <xsl:value-of select="$tableStart" disable-output-escaping="yes"/>


    <tr>
      <!--
      P:Project_x005F_x0020_Name
      P:Project_x005F_x0020_End_x005F_x0020_Date
      P:Project_x005F_x0020_Budget
      P:Project_x005F_x0020_Expenses
      P:Project_x005F_x0020_Status
      -->
      <td>
        <xsl:value-of select="@Project_x005F_x0020_Name"/>
      </td>

      <td align="right">
        <xsl:value-of select="@Project_x005F_x0020_End_x005F_x0020_Date"/>
      </td>

      <td align="right">
        <xsl:call-template name="formatcurrency">
          <xsl:with-param name="value" 
 select="@Project_x005F_x0020_Budget"></xsl:with-param>
        </xsl:call-template>
      </td>

      <td align="right">
        <xsl:call-template name="formatcurrency">
          <xsl:with-param name="value" select="@Project_x005F_x0020_Expenses">
 </xsl:with-param>
        </xsl:call-template>
      </td>

      <td>
        <xsl:value-of select="@Project_x005F_x0020_Status"/>
      </td>

      <!--
        All of the following is commented out to clarify things.
        However, bring it back and stuff it into a <td> to see its
        effect.
      -->
      <!--
        <div id="linkitem" class="item">
          <xsl:if test="string-length($SafeImageUrl) != 0">
            <div class="image-area-left">
              <a href="{$SafeLinkUrl}" target="{$LinkTarget}">
                <img class="image-fixed-width" src="{$SafeImageUrl}" 
                     alt="{@ImageUrlAltText}"/>
              </a>
            </div>
          </xsl:if>
          <div class="link-item">
            <xsl:call-template 
                 name="OuterTemplate.CallPresenceStatusIconTemplate"/>
            <a href="{$SafeLinkUrl}" 
                   target="{$LinkTarget}" title="{@LinkToolTip}">
              <xsl:value-of select="$DisplayTitle"/>
            </a>
            <div class="description">
              <xsl:value-of select="@Description" />
            </div>

          </div>

        </div>

-->
    </tr>

    <!--
      Emit the closing table tag.  If we are not on the last row,
      this will be blank.
    -->
    <xsl:value-of select="$tableEnd" disable-output-escaping="yes"/>

  </xsl:template>

  <xsl:template name="formatcurrency">
    <xsl:param name="value" select="0" />
    <xsl:value-of select='format-number($value, "$DDD,DDD,DDD.DD", "staff")' />

  </xsl:template>

22 thoughts on “Display Content Query Web Part Results in a Grid / Table”

Hannah October 26, 2007 at 7:54 pm

This has been incredibly useful. Thank you!

Reply ↓
Andreas October 20, 2007 at 7:54 pm

Aah… it was because I named my List Style differently and didn’t realise that in the ContentQueryMain.xsl it checks for the "style":

<xsl:when test="@Style=’NameOfMyStyle’">

With that renamed it worked. 🙂

Reply ↓
Andreas October 20, 2007 at 7:54 pm

It almost worked for me: I manage to output the </table> end tag correctly, but the starting tag is missing. It seems the test="$CurPos = 1" does not return true. But why?

Reply ↓
Anand singh Rawat September 29, 2007 at 7:54 pm

Great Post. Paul i have done all the above things. I have a query, how can I achive the sum of "TOTAL ACTUAL Expences" or sum of the value of two columns.

Reply ↓
Lisa May 12, 2007 at 7:54 pm

Have you done any work with creating custom ContentQueryMain and ItemStyle xsl files? The reason I ask is that I don’t want to worry about my custom styles being overwritten with any patches or upgrades. Do you have examples? I’ve tried making an identical copy of the ContentQueryMain.xsl and uploading that new custom copy to the Style Library. When putting a reference to this xsl file in the .webpart’s MainXslLink property, I get 401 not authorized. The custom xsl file is a published version and everyone has read access to it.

Reply ↓
Andries Martins April 20, 2007 at 7:54 pm

fantastic post thanks! Have been battling with this now for the last few days.

Reply ↓
Greg Sheridan April 1, 2007 at 7:54 pm

Hi, this was a really helpful posting. I have it all working, and also implemented Mike Brown’s change so it groups
the results inside the table by whatever I choose as the Group By parameter in the CQWB’s properties.
I made the title a link also, so it works nicely. I still have one problem, though. I’m grouping the results by site name. Inside the table, it groups them nicely, and it looks great, but it’s still printing out all the group
names(in my case the site names) above the table. Does anyone know how to get rid of these?
Thanks,
Greg

Reply ↓
No name January 28, 2007 at 7:54 pm

Nice article. I managed to give my table the look of default Sharepoint Lists by analyzing the source code of the list. Here are the main HTML blocks needed to fit in ItemStyle:

<TABLE width="100%" class="ms-listviewtable" border=0 cellspacing=0 cellpadding=1 dir="None">

<!–HEADER–>
<TR class="ms-viewheadertr" VALIGN=TOP>
<TH nowrap scope="col" class="ms-vh2"><div style="width:100%;position:relative;left:0;top:0;">
<TABLE style="width:100%;" CtxNum="1" height="100%" cellspacing=1 cellpadding=0 class="ms-unselectedtitle">
<TR>
<TD width="100%" Class="ms-vb" nowrap>
Texte du titre ici

</TD>
<TD style="position:absolute;">
</TD>
</TR>
</TABLE></div>
</TH>

<!–Repeat for all header cells–>
</TR>

<!– Table data –>
<TR class="">
<!–Data column, use Paul’s code for the first one with the hyperlink –>
<TD Class="ms-vb2">Data here</TD>

<!–Empty column–>
<TD Class="ms-vb2">
<span dir=None></span><
/TD>

<!–Date column–>
<TD Class="ms-vb2">
<NOBR>11/12/2008</NOBR>
</TD>
</TR>

<!–***Alternate row – Use a new XSL variable that will insert the alternate class based on the current row modulo 2–>
<TR class="ms-alternating">
…
</TR>
</TABLE>

Reply ↓
Ali Zia December 15, 2007 at 7:54 pm

Thatz precisely i was looking for..You rock man..Long live..Love you for the post..

Reply ↓
Mike Brown June 27, 2007 at 7:54 pm

Zoltan,

I was working on the same issue as you. I wanted all my items displayed in a grouped manner rather than just a lits. Here is how I achieved it.

ContentQueryMain.xsl

<xsl:when test="@Style=’Grid’">
        <xsl:apply-templates select="." mode="itemstyle">
          <xsl:with-param name="CurPos" select="$CurPosition" />
          <xsl:with-param name="Last" select="$LastRow" />

<!–add this new section to pass in the parameter indicating a new group has begun–>
          <xsl:with-param name="StartNewGroup" select="@__begingroup" />

        </xsl:apply-templates>
      </xsl:when>

ItemStyle.xsl

Add your parameter

   <xsl:param name="StartNewGroup"/>

Add this text as the first row of data

    <xsl:choose>
      <xsl:when test="$StartNewGroup = ‘True’">
        <tr>
          <td >
            <xsl:call-template name="OuterTemplate.GetGroupName">
              <xsl:with-param name="GroupName" select="@*[name()=$Group]"/>
              <xsl:with-param name="GroupType" select="$GroupType"/>
            </xsl:call-template>
          </td>
        </tr>
      </xsl:when>
      <xsl:otherwise>
      </xsl:otherwise>
    </xsl:choose>

This should take care of your grouping issue in your grid. Each group will now begin with a new row indicating the group name. In my solution I actually added a blank <td/> in the data to indent it as well so the grouping stood out much better.

Site1

    datacolumn1 datacolumn2 datacolumn3 etc

    datacolumn1 datacolumn2 datacolumn3 etc

Site2

    datacolumn1 datacolumn2 datacolumn3 etc

Site3

    datacolumn1 datacolumn2 datacolumn3 etc

    datacolumn1 datacolumn2 datacolumn3 etc

etc.



Reply ↓
Zoltan April 29, 2007 at 7:54 pm

Hello Paul,

Thanks for the post, i managed to organise my query results in a grid, which is very helpful. However, I should go further and group my results based on Sites. At the moment, the Site names are listed first, and then the there is only one big grid gathering all the rows from different sites. Something like this:

Site1 Name

Site2 Name

…

Data in grid for all sites

Any ideas on what I should modify in order to get my data as follows:

Site1 Name

Data in grid for Site1

Site2 Name

Data in grid for Site2

…

Thanks in advance,

Zoltan

Reply ↓
Pierre Joubert April 26, 2007 at 7:54 pm

Fantastic Post, solved my problem I had.

My only issue is displaying the AssignedTo field, I configure it with the "User" field type and the imported webpart then displays the following error:

"There was an error retrieving data to display in this Web Part."

I have tried using all possible field types, with anything other that "User" it does not display the error, but it does not display anything in the field. So I am assuming the User field type is correct, so I must be missing a setting somewhere.

Any ideas on this?

Regards

Pierre

Reply ↓
Charftong April 2, 2007 at 7:54 pm

Great Post!!! Very Very Helpful.

Quick Question, have you done any work on displaying the AssignedTo or ModifiedBy fields with Presence? For some reason, whenever I try to dipslay the Assigned To field in the CQWP, it always displays with as an example "203;#Charf Tong". I cant find a way around this.

Reply ↓
Jennifer Davis March 31, 2007 at 7:54 pm

Paul

Great article, thank you. I am doing something very similar but want to display a link to the project site rather than the item in the list. For example, we have 25 top level project sites and each contain a list with content types. These are Project Name, Division, Description. I want to use the content query web part to pull this data and have succeeded except that by default the URL takes me to the item entry in the list and I really need it to take me to the project site. can you give me any advice?

Thank you

Jen

Reply ↓
Paul Galvin February 20, 2007 at 7:54 pm

Kieren,

I always use visual studio to edit the XSL. It provides color coding and it also has some good intellisense support.

–Paul

Reply ↓
Kieran wrote: February 12, 2007 at 7:54 pm

Hi Paul,

When working with the xml/xsl and content query web part, have you found any good ways to format your xslt? Trying to make changes and test the design is proving a right pain in the a** just using a text editor…

All the best

Reply ↓
Michael Dipay January 14, 2007 at 7:54 pm

Regarding the issue I was having last time where it doesn’t display the images from the grid view but instead displays the text (https://myweb.com/Marketing/images/icn-order.gif,). I manage to resolve it with the help of SharePoint Designer by creating custom view and selecting the custom columns that I want to display. I found out that the images column type are shown as URL(comma) (e.g. https://myweb.com/Marketing/images/icn-order.gif,). The current format is Text, so I have to change it to Picture from the Common xsl:value-of Tasks -> Format as PICTURE. This change the display to the custom images that I wanted to show. I copied the code to show the image ( <img border="0" src="{substring-before(@IcnOrder, ‘, ‘)}" /> ) And in the ItemStyle.xsl file I have to change the @PICTURECOLUMNNAME to the code <img border="0" src="{substring-before(@IcnOrder, ‘, ‘)}" /> . Then save it. Now my table grid results to show the text as well as the custom image type columns.

Reply ↓
Helen January 11, 2007 at 7:54 pm

Hi Paul,

Thanks for the great article!

You mentioned conditional formatting – "You can also put in conditional formatting, such as displaying projects who have exceeded their budget in red." Do you happen to have a code example for that?

Thanks again!

Helen

Reply ↓
Michael Dipay January 8, 2007 at 7:54 pm

Hi Paul,

It was a great article and was able to generate the same results as expected. I have a requirement to show an image in the grid as one of its columns. It’s not displaying the image on the grid but instead displays the url to the image with a (,) comma at the end.
(e.g. https://myweb.com/Marketing/images/icn-order.gif, )
Should I use Image or Picture in the CommonViewFields Field Type? (e.g. InternalColumnName, Image)

Thanks,

Mike

Reply ↓
Saji Ijiyemi August 27, 2010 at 6:43 pm

Your post is exactly what I was looking for. However, I can’t get it to work.

I have documents that are stored in various doc. libraries but classified using a custom class column (choice: 1 or 2. I want to use CQWP to show these documents based on thier class.
I was able to add the CQWP, export it to SPD, configure the itemStyle.xls to show custom fileds in list view. however, I could not successfully implement what you describe here.

These are the columns I want to show in my CQWP:

File Type (to show icon)
File Title
Date Last Modified
Modified By Who
Checked Out To
Checked In Comments

I currently have the result in a list format. How do I change it to a talble format.

Thanks.

Saji

Reply ↓
Lee Goergen May 14, 2012 at 10:06 pm

Sorry for the missspelling on my name not sure where the ” came from.

Reply ↓

Paul Galvin's SharePoint Space